Convert Currency in Number to Words – MS Access

नमस्कार दोस्तो आप सब का एक नए पोस्ट मे स्वागत है इस लेख हम जानेंगे की कैसे MS access मे नंबर को words मे कन्वर्ट करने कर बहुत ही आसान तरीके बताने जा रहा हु ।

ध्यान दें: आपके एक्सेस संस्करण के अनुसार स्क्रीनशॉट्स अलग हो सकते हैं। यदि आपके पास कोई प्रश्न हो, तो नीचे टिप्पणी करें।

1. Go to Create Tab in MS Access, click on Module

दिये गए कोड़ को इसमे paste कर देंगे

Function ConvertCurrencyToEnglish(ByVal MyNumber)
    

    Dim Temp As String
    Dim Rupees As String
    Dim Paise As String
    Dim DecimalPlace As Integer
    Dim Count As Integer
    Dim Place(9) As String

    ' Initialize Place array
    Place(2) = " Thousand "
    Place(3) = " lakh "
    Place(4) = " Crore "

    ' Initialize variables
    If IsNull(MyNumber) Or MyNumber = "" Then MyNumber = 0
    If IsNull(Rupees) Then Rupees = ""
    If IsNull(Paise) Then Paise = ""
    If IsNull(Temp) Then Temp = ""

    ' Convert MyNumber to a string, trimming extra spaces.
    MyNumber = Trim(CStr(MyNumber))

    ' Find decimal place.
    DecimalPlace = InStr(MyNumber, ".")

    ' If we find decimal place...
    If DecimalPlace > 0 Then
        ' Convert Paise
        Temp = Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2)
        Paise = ConvertTens(Temp)

        ' Strip off paise from remainder to convert.
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If

    Count = 1
    If MyNumber <> "" Then
        ' Convert last 3 digits of MyNumber to Indian Rupees.
        Temp = ConvertHundreds(Right(MyNumber, 3))

        If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees

        If Len(MyNumber) > 3 Then
            ' Remove last 3 converted digits from MyNumber.
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
    End If

    ' Convert remaining digits
    Count = 2
    Do While MyNumber <> ""
        Temp = ConvertTens(Right("0" & MyNumber, 2))
        If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
        If Len(MyNumber) > 2 Then
            ' Remove last 2 converted digits from MyNumber.
            MyNumber = Left(MyNumber, Len(MyNumber) - 2)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop

    ' Clean up rupees - no prefix "Rupees"
    If Rupees = "" Then
        Rupees = ""
    ElseIf Rupees = "One" Then
        Rupees = "One"
    End If

    ' Clean up paise
    If Paise = "" Then
        Paise = ""
    ElseIf Paise = "One" Then
        Paise = "One Paise"
    Else
        Paise = Paise & " Paise"
    End If

    ' Return the final result
    If Rupees = "" Then
        ConvertCurrencyToEnglish = Paise & " Only"
    ElseIf Paise = "" Then
        ConvertCurrencyToEnglish = Rupees & " Only"
    Else
        ConvertCurrencyToEnglish = Rupees & " and " & Paise & " Only"
    End If
End Function

Private Function ConvertDigit(ByVal MyDigit) As String
    Select Case Val(MyDigit)
        Case 1: ConvertDigit = "One"
        Case 2: ConvertDigit = "Two"
        Case 3: ConvertDigit = "Three"
        Case 4: ConvertDigit = "Four"
        Case 5: ConvertDigit = "Five"
        Case 6: ConvertDigit = "Six"
        Case 7: ConvertDigit = "Seven"
        Case 8: ConvertDigit = "Eight"
        Case 9: ConvertDigit = "Nine"
        Case Else: ConvertDigit = ""
    End Select
End Function

Private Function ConvertHundreds(ByVal MyNumber As String) As String
    Dim Result As String

    ' Exit if there is nothing to convert.
    If Val(MyNumber) = 0 Then Exit Function

    ' Append leading zeros to number.
    MyNumber = Right("000" & MyNumber, 3)

    ' Do we have a hundreds place digit to convert?
    If Left(MyNumber, 1) <> "0" Then
        Result = ConvertDigit(Left(MyNumber, 1)) & " Hundred "
    End If

    ' Do we have a tens place digit to convert?
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & ConvertTens(Mid(MyNumber, 2))
    Else
        ' If not, then convert the ones place digit.
        Result = Result & ConvertDigit(Mid(MyNumber, 3))
    End If

    ConvertHundreds = Trim(Result)
End Function

Private Function ConvertTens(ByVal MyTens As String) As String
    Dim Result As String

    ' Is value between 10 and 19?
    If Val(Left(MyTens, 1)) = 1 Then
        Select Case Val(MyTens)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else
        ' .. otherwise it's between 20 and 99.
        Select Case Val(Left(MyTens, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select

        ' Convert ones place digit.
        Result = Result & ConvertDigit(Right(MyTens, 1))
    End If

    ConvertTens = Result
End Function

3. अब इसे Ctrl+ C दबा कर yes पर क्लिक करके सेव कर देंगे

4. एक टेक्स्ट बॉक्स लेकर इसे टाइप करेंगे

5. save कर देंगे । नीचे दिये गए विडियो मे बिस्तार से बताया गया है ।